More CMake churn #264

git-svn-id: http://svn.osgeo.org/metacrs/proj/trunk@2632 4e78687f-474d-0410-85f9-8d5e500ac6b2

7 files changed, 127 insertions, 6 deletions

diff --git a/CMakeLists.txt b/CMakeLists.txt
index 81a2e4de..f30b1a6b 100644
--- a/CMakeLists.txt
+++ b/CMakeLists.txt
@@ -32,7 +32,8 @@ colormsg(_HIBLUE_ "Configuring PROJ:")
 #################################################################################
 include(Proj4Version)
 proj_version(MAJOR 4 MINOR 9 PATCH 1)
-set(PROJ_SOVERSION "9.0.0")
+set(PROJ_API_VERSION "9")
+set(PROJ_BUILD_VERSION "9.0.0")
 
 #################################################################################
 # Build features and variants
@@ -45,6 +46,12 @@ include(policies)
 boost_report_value(PROJ_PLATFORM_NAME)
 boost_report_value(PROJ_COMPILER_NAME)
 
+# Set a default build type for single-configuration cmake generators if
+# no build type is set.
+if (NOT CMAKE_CONFIGURATION_TYPES AND NOT CMAKE_BUILD_TYPE)
+  set (CMAKE_BUILD_TYPE Release)
+endif ()
+
 option(PROJ4_TESTS "Enable build of collection of PROJ4 tests" ON)
 boost_report_value(PROJ4_TESTS)
 if(PROJ4_TESTS)
@@ -81,4 +88,5 @@ message(STATUS "")
 add_subdirectory(nad)
 add_subdirectory(src)
 add_subdirectory(man)
+add_subdirectory(cmake)
 
diff --git a/NEWS b/NEWS
index b4fcb06f..73c5c97d 100644
--- a/NEWS
+++ b/NEWS
@@ -31,6 +31,8 @@
  o Regenerate nad/epsg with GDAL r28536 to avoid precision loss in TOWGS84
    parameters, e.g. on Amersfoort / RD EPSG:4289 (#260)
 
+ o Add CMake project-config.cmake scripts (#264 from Charles Karney)
+
 4.9.0 Release Notes
 -------------------
 
diff --git a/cmake/CMakeLists.txt b/cmake/CMakeLists.txt
new file mode 100644
index 00000000..dcb0a61a
--- /dev/null
+++ b/cmake/CMakeLists.txt
@@ -0,0 +1,29 @@
+# proj-config.cmake for the install tree.  It's installed in
+# ${INSTALL_CMAKE_DIR} and @PROJECT_ROOT_DIR@ is the relative
+# path to the root from there.  (Note that the whole install tree can
+# be relocated.)
+if (NOT WIN32)
+  set (INSTALL_CMAKE_DIR "share/cmake/${PROJECT_INTERN_NAME}")
+  set (PROJECT_ROOT_DIR "../../..")
+else ()
+  set (INSTALL_CMAKE_DIR "cmake")
+  set (PROJECT_ROOT_DIR "..")
+endif ()
+
+string(TOLOWER "${PROJECT_INTERN_NAME}" PROJECT_NAME_LOWER)
+configure_file (project-config.cmake.in project-config.cmake @ONLY)
+configure_file (project-config-version.cmake.in
+  project-config-version.cmake @ONLY)
+install (FILES
+  "${CMAKE_CURRENT_BINARY_DIR}/project-config.cmake"
+  DESTINATION "${INSTALL_CMAKE_DIR}"
+  RENAME "${PROJECT_NAME_LOWER}-config.cmake")
+install (FILES
+  "${CMAKE_CURRENT_BINARY_DIR}/project-config-version.cmake"
+  DESTINATION "${INSTALL_CMAKE_DIR}"
+  RENAME "${PROJECT_NAME_LOWER}-config-version.cmake")
+# Make information about the cmake targets (the library and the tools)
+# available.
+install (EXPORT targets
+  FILE ${PROJECT_NAME_LOWER}-targets.cmake
+  DESTINATION "${INSTALL_CMAKE_DIR}")
diff --git a/cmake/project-config-version.cmake.in b/cmake/project-config-version.cmake.in
new file mode 100644
index 00000000..5d57ee15
--- /dev/null
+++ b/cmake/project-config-version.cmake.in
@@ -0,0 +1,48 @@
+# Version checking for @PROJECT_INTERN_NAME@
+
+set (PACKAGE_VERSION "@PROJ_VERSION@")
+set (PACKAGE_VERSION_MAJOR "@PROJ_VERSION_MAJOR@")
+set (PACKAGE_VERSION_MINOR "@PROJ_VERSION_MINOR@")
+set (PACKAGE_VERSION_PATCH "@PROJ_VERSION_PATCH@")
+
+if (NOT PACKAGE_FIND_NAME STREQUAL "@PROJECT_INTERN_NAME@")
+  # Check package name (in particular, because of the way cmake finds
+  # package config files, the capitalization could easily be "wrong").
+  # This is necessary to ensure that the automatically generated
+  # variables, e.g., <package>_FOUND, are consistently spelled.
+  set (REASON "package = @PROJECT_INTERN_NAME@, NOT ${PACKAGE_FIND_NAME}")
+  set (PACKAGE_VERSION_UNSUITABLE TRUE)
+elseif (NOT (APPLE OR (NOT DEFINED CMAKE_SIZEOF_VOID_P) OR
+      CMAKE_SIZEOF_VOID_P EQUAL @CMAKE_SIZEOF_VOID_P@))
+  # Reject if there's a 32-bit/64-bit mismatch (not necessary with Apple
+  # since a multi-architecture library is built for that platform).
+  set (REASON "sizeof(*void) =  @CMAKE_SIZEOF_VOID_P@")
+  set (PACKAGE_VERSION_UNSUITABLE TRUE)
+elseif (MSVC AND NOT MSVC_VERSION STREQUAL "@MSVC_VERSION@")
+  # Reject if there's a mismatch in MSVC compiler versions
+  set (REASON "_MSC_VER = @MSVC_VERSION@")
+  set (PACKAGE_VERSION_UNSUITABLE TRUE)
+elseif (NOT CMAKE_CROSSCOMPILING STREQUAL "@CMAKE_CROSSCOMPILING@")
+  # Reject if there's a mismatch in ${CMAKE_CROSSCOMPILING}
+  set (REASON "cross-compiling = @CMAKE_CROSSCOMPILING@")
+  set (PACKAGE_VERSION_UNSUITABLE TRUE)
+elseif (CMAKE_CROSSCOMPILING AND
+    NOT (CMAKE_SYSTEM_NAME STREQUAL "@CMAKE_SYSTEM_NAME@" AND
+      CMAKE_SYSTEM_PROCESSOR STREQUAL "@CMAKE_SYSTEM_PROCESSOR@"))
+  # Reject if cross-compiling and there's a mismatch in the target system
+  set (REASON "target = @CMAKE_SYSTEM_NAME@-@CMAKE_SYSTEM_PROCESSOR@")
+  set (PACKAGE_VERSION_UNSUITABLE TRUE)
+elseif (PACKAGE_FIND_VERSION)
+  if (PACKAGE_FIND_VERSION VERSION_EQUAL PACKAGE_VERSION)
+    set (PACKAGE_VERSION_EXACT TRUE)
+  elseif (PACKAGE_FIND_VERSION VERSION_LESS PACKAGE_VERSION
+    AND PACKAGE_FIND_VERSION_MAJOR EQUAL PACKAGE_VERSION_MAJOR)
+    set (PACKAGE_VERSION_COMPATIBLE TRUE)
+  endif ()
+endif ()
+
+# If unsuitable, append the reason to the package version so that it's
+# visible to the user.
+if (PACKAGE_VERSION_UNSUITABLE)
+  set (PACKAGE_VERSION "${PACKAGE_VERSION} (${REASON})")
+endif ()
diff --git a/cmake/project-config.cmake.in b/cmake/project-config.cmake.in
new file mode 100644
index 00000000..6110dc61
--- /dev/null
+++ b/cmake/project-config.cmake.in
@@ -0,0 +1,28 @@
+# Configure @PROJECT_INTERN_NAME@
+#
+# Set
+#  @PROJECT_INTERN_NAME@_FOUND = 1
+#  @PROJECT_INTERN_NAME@_INCLUDE_DIRS = /usr/local/include
+#  @PROJECT_INTERN_NAME@_LIBRARIES = proj
+#  @PROJECT_INTERN_NAME@_LIBRARY_DIRS = /usr/local/lib
+#  @PROJECT_INTERN_NAME@_BINARY_DIRS = /usr/local/bin
+#  @PROJECT_INTERN_NAME@_VERSION = 4.9.1 (for example)
+
+message (STATUS "Reading ${CMAKE_CURRENT_LIST_FILE}")
+# @PROJECT_INTERN_NAME@_VERSION is set by version file
+message (STATUS
+  "@PROJECT_INTERN_NAME@ configuration, version ${@PROJECT_INTERN_NAME@_VERSION}")
+
+# Tell the user project where to find our headers and libraries
+get_filename_component (_DIR ${CMAKE_CURRENT_LIST_FILE} PATH)
+get_filename_component (_ROOT "${_DIR}/@PROJECT_ROOT_DIR@" ABSOLUTE)
+set (@PROJECT_INTERN_NAME@_INCLUDE_DIRS "${_ROOT}/@INCLUDEDIR@")
+set (@PROJECT_INTERN_NAME@_LIBRARY_DIRS "${_ROOT}/@LIBDIR@")
+set (@PROJECT_INTERN_NAME@_BINARY_DIRS "${_ROOT}/@BINDIR@")
+
+set (@PROJECT_INTERN_NAME@_LIBRARIES proj)
+# Read in the exported definition of the library
+include ("${_DIR}/@PROJECT_NAME_LOWER@-targets.cmake")
+
+unset (_ROOT)
+unset (_DIR)
diff --git a/src/CMakeLists.txt b/src/CMakeLists.txt
index 77d5d6f5..7c84fabc 100644
--- a/src/CMakeLists.txt
+++ b/src/CMakeLists.txt
@@ -11,14 +11,14 @@ option(BUILD_NAD2BIN "Build nad2bin (format conversion tool) " ON)
 if(NOT MSVC)
   if (NOT APPLE)
     # Use relative path so that package is relocatable
-    set(CMAKE_INSTALL_RPATH "\$ORIGIN/../lib")
+    set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${LIBDIR}")
   else ()
-    set (CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/lib")
+    set (CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LIBDIR}")
     # TO DO: cmake 2.8.12 introduces a way to make the install tree
     # relocatable with OSX via
     # (1) set(CMAKE_MACOSX_RPATH ON) and
     # (2) setting the INSTALL_RPATH property on the executables to
-    # "@loader_path/../lib"
+    # "@loader_path/../${LIBDIR}"
   endif ()
 endif ()
 
diff --git a/src/lib_proj.cmake b/src/lib_proj.cmake
index e0ed351b..8111c7aa 100644
--- a/src/lib_proj.cmake
+++ b/src/lib_proj.cmake
@@ -264,17 +264,20 @@ add_library( ${PROJ_CORE_TARGET}
 if(WIN32)
   set_target_properties(${PROJ_CORE_TARGET}
     PROPERTIES
+    VERSION "${${PROJECT_INTERN_NAME}_BUILD_VERSION}"
     OUTPUT_NAME "${PROJ_CORE_TARGET_OUTPUT_NAME}"
     CLEAN_DIRECT_OUTPUT 1)
 elseif(BUILD_FRAMEWORKS_AND_BUNDLE)
   set_target_properties(${PROJ_CORE_TARGET}
     PROPERTIES
+    VERSION "${${PROJECT_INTERN_NAME}_BUILD_VERSION}"
     INSTALL_NAME_DIR ${PROJ_INSTALL_NAME_DIR}
     CLEAN_DIRECT_OUTPUT 1)
 else()
   set_target_properties(${PROJ_CORE_TARGET}
     PROPERTIES
-    SOVERSION "${${PROJECT_INTERN_NAME}_SOVERSION}"
+    VERSION "${${PROJECT_INTERN_NAME}_BUILD_VERSION}"
+    SOVERSION "${${PROJECT_INTERN_NAME}_API_VERSION}"
     CLEAN_DIRECT_OUTPUT 1)
 endif()
 
@@ -288,7 +291,9 @@ set_target_properties(${PROJ_CORE_TARGET}
 set(PROJ_LIBRARIES ${PROJ_CORE_TARGET} )
 if(UNIX AND BUILD_LIBPROJ_SHARED)
     find_library(M_LIB m)
-    TARGET_LINK_LIBRARIES(${PROJ_CORE_TARGET} ${M_LIB})
+    if(M_LIB)
+      TARGET_LINK_LIBRARIES(${PROJ_CORE_TARGET} -lm)
+    endif()
 endif(UNIX AND BUILD_LIBPROJ_SHARED)
 if(USE_THREAD AND Threads_FOUND AND CMAKE_USE_PTHREADS_INIT AND BUILD_LIBPROJ_SHARED)
    TARGET_LINK_LIBRARIES(${PROJ_CORE_TARGET} ${CMAKE_THREAD_LIBS_INIT})
@@ -299,6 +304,7 @@ endif(USE_THREAD AND Threads_FOUND AND CMAKE_USE_PTHREADS_INIT AND BUILD_LIBPROJ
 # install
 ##############################################
 install(TARGETS ${PROJ_CORE_TARGET}
+        EXPORT targets
         RUNTIME DESTINATION ${BINDIR}
         LIBRARY DESTINATION ${LIBDIR}
         ARCHIVE DESTINATION ${LIBDIR}