[rollup:2021-07-06] Rollup PR (#18838)

* [rollup:2021-07-06 1/8] PR #18272 (@strega-nil)

[scripts-audit] vcpkg_from_*

* [rollup:2021-07-06 2/8] PR #18319 (@strega-nil)

[scripts-audit] add guidelines for cmake

* [rollup 2021-07-06 3/8] PR #18410 (@mheyman)

[vcpkg-cmake-config] documentation fix

* [rollup:2021-07-06 4/8] PR #18488 (@strega-nil)

[scripts-audit] vcpkg_execute_*

* [rollup:2021-07-06 5/8] PR #18517 (@strega-nil)

[scripts-audit] vcpkg_extract_source_archive

* [rollup:2021-07-06 6/8] PR #18674 (@NancyLi1013)

[vcpkg doc] Update examples

* [rollup:2021-07-06 7/8] PR #18695 (@JackBoosY)

[vcpkg] Update the minimum version of vcpkg

* [rollup:2021-07-06 8/8] PR #18758 (@ras0219-msft)

[vcpkg_from_git] Fix error if downloads folder does not exist

* build docs!

* fix bond:*-windows

* fix nmap

Co-authored-by: nicole mazzuca <mazzucan@outlook.com>
Co-authored-by: Michael Heyman <Michael.Heyman@jhuapl.edu>
Co-authored-by: NancyLi1013 <lirui09@beyondsoft.com>
Co-authored-by: JackBoosY <yuzaiyang@beyondsoft.com>
Co-authored-by: Robert Schumacher <ras0219@outlook.com>

1 files changed, 87 insertions, 99 deletions

diff --git a/scripts/cmake/vcpkg_from_gitlab.cmake b/scripts/cmake/vcpkg_from_gitlab.cmake
index 865c5326e..75b09601f 100644
--- a/scripts/cmake/vcpkg_from_gitlab.cmake
+++ b/scripts/cmake/vcpkg_from_gitlab.cmake
@@ -70,132 +70,120 @@ This exports the `VCPKG_HEAD_VERSION` variable during head builds.
 include(vcpkg_execute_in_download_mode)
 
 function(vcpkg_from_gitlab)
-    set(oneValueArgs OUT_SOURCE_PATH GITLAB_URL USER REPO REF SHA512 HEAD_REF FILE_DISAMBIGUATOR)
-    set(multipleValuesArgs PATCHES)
-    # parse parameters such that semicolons in options arguments to COMMAND don't get erased
-    cmake_parse_arguments(PARSE_ARGV 0 _vdud "" "${oneValueArgs}" "${multipleValuesArgs}")
+    cmake_parse_arguments(PARSE_ARGV 0 "arg"
+        ""
+        "OUT_SOURCE_PATH;GITLAB_URL;REPO;REF;SHA512;HEAD_REF;FILE_DISAMBIGUATOR"
+        "PATCHES")
 
-    if(NOT DEFINED _vdud_GITLAB_URL)
-        message(FATAL_ERROR "GITLAB_URL must be specified.")
+    if(DEFINED arg_UNPARSED_ARGUMENTS)
+        message(WARNING "vcpkg_from_gitlab was passed extra arguments: ${arg_UNPARSED_ARGUMENTS}")
     endif()
 
-    if(NOT DEFINED _vdud_OUT_SOURCE_PATH)
-        message(FATAL_ERROR "OUT_SOURCE_PATH must be specified.")
+    if(NOT DEFINED arg_GITLAB_URL)
+        message(FATAL_ERROR "GITLAB_URL must be specified.")
     endif()
 
-    if((DEFINED _vdud_REF AND NOT DEFINED _vdud_SHA512) OR (NOT DEFINED _vdud_REF AND DEFINED _vdud_SHA512))
+    if(DEFINED arg_REF AND NOT DEFINED arg_SHA512)
         message(FATAL_ERROR "SHA512 must be specified if REF is specified.")
     endif()
+    if(NOT DEFINED arg_REF AND DEFINED arg_SHA512)
+        message(FATAL_ERROR "REF must be specified if SHA512 is specified.")
+    endif()
 
-    if(NOT DEFINED _vdud_REPO)
-        message(FATAL_ERROR "REPO must be specified.")
+    if(NOT DEFINED arg_OUT_SOURCE_PATH)
+        message(FATAL_ERROR "OUT_SOURCE_PATH must be specified.")
+    endif()
+    if(NOT DEFINED arg_REPO)
+        message(FATAL_ERROR "The GitHub repository must be specified.")
     endif()
 
-    if(NOT DEFINED _vdud_REF AND NOT DEFINED _vdud_HEAD_REF)
-        message(FATAL_ERROR "At least one of REF and HEAD_REF must be specified.")
+    set(headers_param "")
+    if(DEFINED arg_AUTHORIZATION_TOKEN)
+        set(headers_param "HEADERS" "Authorization: token ${arg_AUTHORIZATION_TOKEN}")
     endif()
 
-    if(VCPKG_USE_HEAD_VERSION AND NOT DEFINED _vdud_HEAD_REF)
-        message(STATUS "Package does not specify HEAD_REF. Falling back to non-HEAD version.")
-        set(VCPKG_USE_HEAD_VERSION OFF)
+    if(NOT DEFINED arg_REF AND NOT DEFINED arg_HEAD_REF)
+        message(FATAL_ERROR "At least one of REF or HEAD_REF must be specified.")
     endif()
 
-    string(REPLACE "/" ";" GITLAB_REPO_LINK ${_vdud_REPO})
-    
-    list(LENGTH GITLAB_REPO_LINK len)
-    if(${len} EQUAL "2")
-		list(GET GITLAB_REPO_LINK 0 ORG_NAME)
-		list(GET GITLAB_REPO_LINK 1 REPO_NAME)
-		set(GITLAB_LINK ${_vdud_GITLAB_URL}/${ORG_NAME}/${REPO_NAME})
-	endif()
-	
-	if(${len} EQUAL "3")
-		list(GET GITLAB_REPO_LINK 0 ORG_NAME)
-		list(GET GITLAB_REPO_LINK 1 GROUP_NAME)
-		list(GET GITLAB_REPO_LINK 2 REPO_NAME)
-		set(GITLAB_LINK ${_vdud_GITLAB_URL}/${ORG_NAME}/${GROUP_NAME}/${REPO_NAME})
-	endif()
-    
-    # Handle --no-head scenarios
-    if(NOT VCPKG_USE_HEAD_VERSION)
-        if(NOT _vdud_REF)
-            message(FATAL_ERROR "Package does not specify REF. It must built using --head.")
-        endif()
+    if(arg_REPO MATCHES [[^([^/]*)/([^/]*)$]]) # 2 elements
+        set(org_name "${CMAKE_MATCH_1}")
+        set(repo_name "${CMAKE_MATCH_2}")
+        set(gitlab_link "${arg_GITLAB_URL}/${org_name}/${repo_name}")
+    elseif(arg_REPO MATCHES [[^([^/]*)/([^/]*)/([^/]*)$]]) # 3 elements
+        set(org_name "${CMAKE_MATCH_1}")
+        set(group_name "${CMAKE_MATCH_2}")
+        set(repo_name "${CMAKE_MATCH_3}")
+        set(gitlab_link "${arg_GITLAB_URL}/${org_name}/${group_name}/${repo_name}")
+    else()
+        message(FATAL_ERROR "REPO (${arg_REPO}) is not a valid repo name. It must be:
+    - an organization name followed by a repository name separated by a single slash, or
+    - an organization name, group name, and repository name separated by slashes.")
+    endif()
 
-        string(REPLACE "/" "-" SANITIZED_REF "${_vdud_REF}")
-        set(downloaded_file_name "${ORG_NAME}-${REPO_NAME}-${SANITIZED_REF}")
-        if (_vdud_FILE_DISAMBIGUATOR)
-            set(downloaded_file_name "${downloaded_file_name}-${_vdud_FILE_DISAMBIGUATOR}")
+    set(redownload_param "")
+    set(working_directory_param "")
+    set(sha512_param "SHA512" "${arg_SHA512}")
+    set(ref_to_use "${arg_REF}")
+    if(VCPKG_USE_HEAD_VERSION)
+        if(DEFINED arg_HEAD_REF)
+            set(redownload_param "ALWAYS_REDOWNLOAD")
+            set(sha512_param "SKIP_SHA512")
+            set(working_directory_param "WORKING_DIRECTORY" "${CURRENT_BUILDTREES_DIR}/src/head")
+            set(ref_to_use "${arg_HEAD_REF}")
+        else()
+            message(STATUS "Package does not specify HEAD_REF. Falling back to non-HEAD version.")
         endif()
+    elseif(NOT DEFINED arg_REF)
+        message(FATAL_ERROR "Package does not specify REF. It must be built using --head.")
+    endif()
 
-        set(downloaded_file_name "${downloaded_file_name}.tar.gz")
-
-        vcpkg_download_distfile(ARCHIVE
-            URLS "${GITLAB_LINK}/-/archive/${_vdud_REF}/${REPO_NAME}-${_vdud_REF}.tar.gz"
-            SHA512 "${_vdud_SHA512}"
-            FILENAME "${downloaded_file_name}"
-        )
-
-        vcpkg_extract_source_archive_ex(
-            OUT_SOURCE_PATH SOURCE_PATH
-            ARCHIVE "${ARCHIVE}"
-            REF "${SANITIZED_REF}"
-            PATCHES ${_vdud_PATCHES}
-        )
-
-        set(${_vdud_OUT_SOURCE_PATH} "${SOURCE_PATH}" PARENT_SCOPE)
-        return()
+    # avoid using either - or _, to allow both `foo/bar` and `foo-bar` to coexist
+    # we assume that no one will name a ref "foo_-bar"
+    string(REPLACE "/" "_-" sanitized_ref "${ref_to_use}")
+    if(DEFINED arg_FILE_DISAMBIGUATOR AND NOT VCPKG_USE_HEAD_VERSION)
+        set(downloaded_file_name "${org_name}-${repo_name}-${sanitized_ref}-${arg_FILE_DISAMBIGUATOR}.tar.gz")
+    else()
+        set(downloaded_file_name "${org_name}-${repo_name}-${sanitized_ref}.tar.gz")
     endif()
 
-    # The following is for --head scenarios
-    set(URL "${GITLAB_LINK}/-/archive/${_vdud_HEAD_REF}/${_vdud_HEAD_REF}.tar.gz")
-    string(REPLACE "/" "-" SANITIZED_HEAD_REF "${_vdud_HEAD_REF}")
-    set(downloaded_file_name "${ORG_NAME}-${REPO_NAME}-${SANITIZED_HEAD_REF}.tar.gz")
-    set(downloaded_file_path "${DOWNLOADS}/${downloaded_file_name}")
 
-    if(_VCPKG_NO_DOWNLOADS)
-        if(NOT EXISTS ${downloaded_file_path} OR NOT EXISTS ${downloaded_file_path}.version)
-            message(FATAL_ERROR "Downloads are disabled, but '${downloaded_file_path}' does not exist.")
-        endif()
-        message(STATUS "Using cached ${downloaded_file_path}")
-    else()
-        if(EXISTS ${downloaded_file_path})
-            message(STATUS "Purging cached ${downloaded_file_path} to fetch latest (use --no-downloads to suppress)")
-            file(REMOVE ${downloaded_file_path})
+    # exports VCPKG_HEAD_VERSION to the caller. This will get picked up by ports.cmake after the build.
+    if(VCPKG_USE_HEAD_VERSION)
+        # There are issues with the Gitlab API project paths being URL-escaped, so we use git here to get the head revision
+        vcpkg_execute_in_download_mode(COMMAND ${GIT} ls-remote
+            "${gitlab_link}.git" "${arg_HEAD_REF}"
+            RESULT_VARIABLE git_result
+            OUTPUT_VARIABLE git_output
+        )
+        if(NOT git_result EQUAL 0)
+            message(FATAL_ERROR "git ls-remote failed to read ref data of repository: '${gitlab_link}'")
         endif()
-        if(EXISTS ${downloaded_file_path}.version)
-            file(REMOVE ${downloaded_file_path}.version)
+        if(NOT git_output MATCHES "^([a-f0-9]*)\t")
+            message(FATAL_ERROR "git ls-remote returned unexpected result:
+${git_output}
+")
         endif()
-        if(EXISTS ${CURRENT_BUILDTREES_DIR}/src/head)
-            file(REMOVE_RECURSE ${CURRENT_BUILDTREES_DIR}/src/head)
+        # When multiple vcpkg_from_gitlab's are used after each other, only use the version from the first (hopefully the primary one).
+        if(NOT DEFINED VCPKG_HEAD_VERSION)
+            set(VCPKG_HEAD_VERSION "${CMAKE_MATCH_1}" PARENT_SCOPE)
         endif()
-
-        vcpkg_download_distfile(ARCHIVE
-            URLS ${URL}
-            FILENAME ${downloaded_file_name}
-            SKIP_SHA512
-        )
     endif()
 
-    # There are issues with the Gitlab API project paths being URL-escaped, so we use git here to get the head revision
-    vcpkg_execute_in_download_mode(COMMAND ${GIT} ls-remote
-        "${GITLAB_LINK}.git" "${_vdud_HEAD_REF}"
-        RESULT_VARIABLE _git_result
-        OUTPUT_VARIABLE _git_output
+    # download the file information from gitlab
+    vcpkg_download_distfile(archive
+        URLS "${gitlab_link}/-/archive/${ref_to_use}/${repo_name}-${ref_to_use}.tar.gz"
+        FILENAME "${downloaded_file_name}"
+        ${headers_param}
+        ${sha512_param}
+        ${redownload_param}
     )
-    string(REGEX MATCH "[a-f0-9]+" _version "${_git_output}")
-    # exports VCPKG_HEAD_VERSION to the caller. This will get picked up by ports.cmake after the build.
-    # When multiple vcpkg_from_gitlab's are used after each other, only use the version from the first (hopefully the primary one).
-    if(NOT DEFINED VCPKG_HEAD_VERSION)
-        set(VCPKG_HEAD_VERSION ${_version} PARENT_SCOPE)
-    endif()
-
     vcpkg_extract_source_archive_ex(
         OUT_SOURCE_PATH SOURCE_PATH
-        ARCHIVE "${downloaded_file_path}"
-        REF "${SANITIZED_HEAD_REF}"
-        WORKING_DIRECTORY ${CURRENT_BUILDTREES_DIR}/src/head
-        PATCHES ${_vdud_PATCHES}
+        ARCHIVE "${archive}"
+        REF "${sanitized_ref}"
+        PATCHES ${arg_PATCHES}
+        ${working_directory_param}
     )
-    set(${_vdud_OUT_SOURCE_PATH} "${SOURCE_PATH}" PARENT_SCOPE)
+    set("${arg_OUT_SOURCE_PATH}" "${SOURCE_PATH}" PARENT_SCOPE)
 endfunction()