Merge branch 'master' into vtk-components

9 files changed, 311 insertions, 111 deletions

diff --git a/scripts/cmake/vcpkg_acquire_depot_tools.cmake b/scripts/cmake/vcpkg_acquire_depot_tools.cmake
index 1cc375725..009ba40f1 100644
--- a/scripts/cmake/vcpkg_acquire_depot_tools.cmake
+++ b/scripts/cmake/vcpkg_acquire_depot_tools.cmake
@@ -26,7 +26,7 @@ function(vcpkg_acquire_depot_tools PATH_TO_ROOT_OUT)
         set(download_success 1)
       endif()
 
-      if (NOT ${download_success})
+      if (NOT download_success)
         message(FATAL_ERROR
           "\n"
           "    Failed to download file.\n"
diff --git a/scripts/cmake/vcpkg_build_cmake.cmake b/scripts/cmake/vcpkg_build_cmake.cmake
index 18e2a8b00..5dc81ec09 100644
--- a/scripts/cmake/vcpkg_build_cmake.cmake
+++ b/scripts/cmake/vcpkg_build_cmake.cmake
@@ -1,41 +1,76 @@
+## # vcpkg_build_cmake
+##
+## Build a cmake project.
+##
+## ## Usage:
+## ```cmake
+## vcpkg_build_cmake([DISABLE_PARALLEL] [TARGET <target>])
+## ```
+##
+## ## Parameters:
+## ### DISABLE_PARALLEL
+## The underlying buildsystem will be instructed to not parallelize
+##
+## ### TARGET
+## The target passed to the cmake build command (`cmake --build . --target <target>`). If not specified, no target will
+## be passed.
+##
+## ## Notes:
+## This command should be preceeded by a call to [`vcpkg_configure_cmake()`](vcpkg_configure_cmake.md).
+## You can use the alias [`vcpkg_install_cmake()`](vcpkg_configure_cmake.md) function if your CMake script supports the
+## "install" target
+##
+## ## Examples:
+##
+## * [zlib](https://github.com/Microsoft/vcpkg/blob/master/ports/zlib/portfile.cmake)
+## * [cpprestsdk](https://github.com/Microsoft/vcpkg/blob/master/ports/cpprestsdk/portfile.cmake)
+## * [poco](https://github.com/Microsoft/vcpkg/blob/master/ports/poco/portfile.cmake)
+## * [opencv](https://github.com/Microsoft/vcpkg/blob/master/ports/opencv/portfile.cmake)
 function(vcpkg_build_cmake)
-    cmake_parse_arguments(_bc "MSVC_64_TOOLSET;DISABLE_PARALLEL" "" "" ${ARGN})
+    cmake_parse_arguments(_bc "DISABLE_PARALLEL" "TARGET;LOGFILE_ROOT" "" ${ARGN})
 
-    set(MSVC_EXTRA_ARGS
-        "/p:VCPkgLocalAppDataDisabled=true"
-        "/p:UseIntelMKL=No"
-    )
-
-    # Specifies the architecture of the toolset, NOT the architecture of the produced binary
-    # This can help libraries that cause the linker to run out of memory.
-    # https://support.microsoft.com/en-us/help/2891057/linker-fatal-error-lnk1102-out-of-memory
-    if (_bc_MSVC_64_TOOLSET)
-        list(APPEND MSVC_EXTRA_ARGS "/p:PreferredToolArchitecture=x64")
+    if(NOT _bc_LOGFILE_ROOT)
+        set(_bc_LOGFILE_ROOT "build")
     endif()
 
-    if (NOT _bc_DISABLE_PARALLEL)
-        list(APPEND MSVC_EXTRA_ARGS "/m")
+    if(_VCPKG_CMAKE_GENERATOR MATCHES "Ninja")
+        set(BUILD_ARGS "-v") # verbose output
+        if (_bc_DISABLE_PARALLEL)
+            list(APPEND BUILD_ARGS "-j1")
+        endif()
+    elseif(_VCPKG_CMAKE_GENERATOR MATCHES "Visual Studio")
+        set(BUILD_ARGS
+            "/p:VCPkgLocalAppDataDisabled=true"
+            "/p:UseIntelMKL=No"
+        )
+        if (NOT _bc_DISABLE_PARALLEL)
+            list(APPEND BUILD_ARGS "/m")
+        endif()
+    elseif(_VCPKG_CMAKE_GENERATOR MATCHES "NMake")
+        # No options are currently added for nmake builds
+    else()
+        message(FATAL_ERROR "Unrecognized GENERATOR setting from vcpkg_configure_cmake(). Valid generators are: Ninja, Visual Studio, and NMake Makefiles")
     endif()
 
-    if(EXISTS ${CURRENT_BUILDTREES_DIR}/${TARGET_TRIPLET}-rel/build.ninja)
-        set(BUILD_ARGS -v) # verbose output
+    if(_bc_TARGET)
+        set(TARGET_PARAM "--target" ${_bc_TARGET})
     else()
-        set(BUILD_ARGS ${MSVC_EXTRA_ARGS})
+        set(TARGET_PARAM)
     endif()
 
     message(STATUS "Build ${TARGET_TRIPLET}-rel")
     vcpkg_execute_required_process(
-        COMMAND ${CMAKE_COMMAND} --build . --config Release -- ${BUILD_ARGS}
+        COMMAND ${CMAKE_COMMAND} --build . --config Release ${TARGET_PARAM} -- ${BUILD_ARGS}
         WORKING_DIRECTORY ${CURRENT_BUILDTREES_DIR}/${TARGET_TRIPLET}-rel
-        LOGNAME build-${TARGET_TRIPLET}-rel
+        LOGNAME ${_bc_LOGFILE_ROOT}-${TARGET_TRIPLET}-rel
     )
     message(STATUS "Build ${TARGET_TRIPLET}-rel done")
 
     message(STATUS "Build ${TARGET_TRIPLET}-dbg")
     vcpkg_execute_required_process(
-        COMMAND ${CMAKE_COMMAND} --build . --config Debug -- ${BUILD_ARGS}
+        COMMAND ${CMAKE_COMMAND} --build . --config Debug ${TARGET_PARAM} -- ${BUILD_ARGS}
         WORKING_DIRECTORY ${CURRENT_BUILDTREES_DIR}/${TARGET_TRIPLET}-dbg
-        LOGNAME build-${TARGET_TRIPLET}-dbg
+        LOGNAME ${_bc_LOGFILE_ROOT}-${TARGET_TRIPLET}-dbg
     )
     message(STATUS "Build ${TARGET_TRIPLET}-dbg done")
 endfunction()
diff --git a/scripts/cmake/vcpkg_common_functions.cmake b/scripts/cmake/vcpkg_common_functions.cmake
index 29f0f8dff..81e8e5813 100644
--- a/scripts/cmake/vcpkg_common_functions.cmake
+++ b/scripts/cmake/vcpkg_common_functions.cmake
@@ -6,6 +6,7 @@ include(vcpkg_execute_required_process_repeat)
 include(vcpkg_find_acquire_program)
 include(vcpkg_fixup_cmake_targets)
 include(vcpkg_from_github)
+include(vcpkg_from_bitbucket)
 include(vcpkg_build_cmake)
 include(vcpkg_build_msbuild)
 include(vcpkg_build_qmake)
diff --git a/scripts/cmake/vcpkg_configure_cmake.cmake b/scripts/cmake/vcpkg_configure_cmake.cmake
index 07acfc8ea..bfb6a19fd 100644
--- a/scripts/cmake/vcpkg_configure_cmake.cmake
+++ b/scripts/cmake/vcpkg_configure_cmake.cmake
@@ -78,14 +78,20 @@ function(vcpkg_configure_cmake)
         set(GENERATOR "Visual Studio 15 2017")
     elseif(VCPKG_CMAKE_SYSTEM_NAME STREQUAL "WindowsStore" AND TRIPLET_SYSTEM_ARCH MATCHES "x64" AND VCPKG_PLATFORM_TOOLSET MATCHES "v141")
         set(GENERATOR "Visual Studio 15 2017 Win64")
-    elseif(VCPKG_CMAKE_SYSTEM_NAME STREQUAL "WindowsStore" AND TRIPLET_SYSTEM_ARCH MATCHES "arm" AND VCPKG_PLATFORM_TOOLSET MATCHES "v141")
+    elseif(VCPKG_CMAKE_SYSTEM_NAME STREQUAL "WindowsStore" AND TRIPLET_SYSTEM_ARCH STREQUAL "arm" AND VCPKG_PLATFORM_TOOLSET MATCHES "v141")
         set(GENERATOR "Visual Studio 15 2017 ARM")
+    elseif(VCPKG_CMAKE_SYSTEM_NAME STREQUAL "WindowsStore" AND TRIPLET_SYSTEM_ARCH STREQUAL "arm64" AND VCPKG_PLATFORM_TOOLSET MATCHES "v141")
+        set(GENERATOR "Visual Studio 15 2017")    
+        set(ARCH "ARM64")
     elseif(TRIPLET_SYSTEM_ARCH MATCHES "x86" AND VCPKG_PLATFORM_TOOLSET MATCHES "v141")
         set(GENERATOR "Visual Studio 15 2017")
     elseif(TRIPLET_SYSTEM_ARCH MATCHES "x64" AND VCPKG_PLATFORM_TOOLSET MATCHES "v141")
         set(GENERATOR "Visual Studio 15 2017 Win64")
-    elseif(TRIPLET_SYSTEM_ARCH MATCHES "arm" AND VCPKG_PLATFORM_TOOLSET MATCHES "v141")
+    elseif(TRIPLET_SYSTEM_ARCH STREQUAL "arm" AND VCPKG_PLATFORM_TOOLSET MATCHES "v141")
         set(GENERATOR "Visual Studio 15 2017 ARM")
+    elseif(TRIPLET_SYSTEM_ARCH STREQUAL "arm64" AND VCPKG_PLATFORM_TOOLSET MATCHES "v141")
+        set(GENERATOR "Visual Studio 15 2017")
+        set(ARCH "ARM64")
     endif()
     
     # If we use Ninja, make sure it's on PATH
@@ -139,24 +145,30 @@ function(vcpkg_configure_cmake)
         "-DCMAKE_ERROR_ON_ABSOLUTE_INSTALL_DESTINATION=ON"
     )
 
+    if(DEFINED ARCH)
+        list(APPEND _csc_OPTIONS
+            "-A${ARCH}"
+        )
+    endif()
+
     if(DEFINED VCPKG_CRT_LINKAGE AND VCPKG_CRT_LINKAGE STREQUAL dynamic)
         list(APPEND _csc_OPTIONS_DEBUG
-            "-DCMAKE_CXX_FLAGS_DEBUG=/D_DEBUG /MDd /Zi /Ob0 /Od /RTC1 ${VCPKG_CXX_FLAGS_DEBUG}"
-            "-DCMAKE_C_FLAGS_DEBUG=/D_DEBUG /MDd /Zi /Ob0 /Od /RTC1 ${VCPKG_C_FLAGS_DEBUG}"
+            "-DCMAKE_CXX_FLAGS_DEBUG=/D_DEBUG /MDd /Z7 /Ob0 /Od /RTC1 ${VCPKG_CXX_FLAGS_DEBUG}"
+            "-DCMAKE_C_FLAGS_DEBUG=/D_DEBUG /MDd /Z7 /Ob0 /Od /RTC1 ${VCPKG_C_FLAGS_DEBUG}"
         )
         list(APPEND _csc_OPTIONS_RELEASE
-            "-DCMAKE_CXX_FLAGS_RELEASE=/MD /O2 /Oi /Gy /DNDEBUG /Zi ${VCPKG_CXX_FLAGS_RELEASE}"
-            "-DCMAKE_C_FLAGS_RELEASE=/MD /O2 /Oi /Gy /DNDEBUG /Zi ${VCPKG_C_FLAGS_RELEASE}"
+            "-DCMAKE_CXX_FLAGS_RELEASE=/MD /O2 /Oi /Gy /DNDEBUG /Z7 ${VCPKG_CXX_FLAGS_RELEASE}"
+            "-DCMAKE_C_FLAGS_RELEASE=/MD /O2 /Oi /Gy /DNDEBUG /Z7 ${VCPKG_C_FLAGS_RELEASE}"
         )
 
     elseif(DEFINED VCPKG_CRT_LINKAGE AND VCPKG_CRT_LINKAGE STREQUAL static)
         list(APPEND _csc_OPTIONS_DEBUG
-            "-DCMAKE_CXX_FLAGS_DEBUG=/D_DEBUG /MTd /Zi /Ob0 /Od /RTC1 ${VCPKG_CXX_FLAGS_DEBUG}"
-            "-DCMAKE_C_FLAGS_DEBUG=/D_DEBUG /MTd /Zi /Ob0 /Od /RTC1 ${VCPKG_C_FLAGS_DEBUG}"
+            "-DCMAKE_CXX_FLAGS_DEBUG=/D_DEBUG /MTd /Z7 /Ob0 /Od /RTC1 ${VCPKG_CXX_FLAGS_DEBUG}"
+            "-DCMAKE_C_FLAGS_DEBUG=/D_DEBUG /MTd /Z7 /Ob0 /Od /RTC1 ${VCPKG_C_FLAGS_DEBUG}"
         )
         list(APPEND _csc_OPTIONS_RELEASE
-            "-DCMAKE_CXX_FLAGS_RELEASE=/MT /O2 /Oi /Gy /DNDEBUG /Zi ${VCPKG_CXX_FLAGS_RELEASE}"
-            "-DCMAKE_C_FLAGS_RELEASE=/MT /O2 /Oi /Gy /DNDEBUG /Zi ${VCPKG_C_FLAGS_RELEASE}"
+            "-DCMAKE_CXX_FLAGS_RELEASE=/MT /O2 /Oi /Gy /DNDEBUG /Z7 ${VCPKG_CXX_FLAGS_RELEASE}"
+            "-DCMAKE_C_FLAGS_RELEASE=/MT /O2 /Oi /Gy /DNDEBUG /Z7 ${VCPKG_C_FLAGS_RELEASE}"
         )
     endif()
 
@@ -188,4 +200,6 @@ function(vcpkg_configure_cmake)
         LOGNAME config-${TARGET_TRIPLET}-dbg
     )
     message(STATUS "Configuring ${TARGET_TRIPLET}-dbg done")
+
+    set(_VCPKG_CMAKE_GENERATOR "${GENERATOR}" PARENT_SCOPE)
 endfunction()
\ No newline at end of file
diff --git a/scripts/cmake/vcpkg_configure_meson.cmake b/scripts/cmake/vcpkg_configure_meson.cmake
index 277f91e11..143bb74de 100644
--- a/scripts/cmake/vcpkg_configure_meson.cmake
+++ b/scripts/cmake/vcpkg_configure_meson.cmake
@@ -9,17 +9,17 @@ function(vcpkg_configure_meson)
     set(MESON_COMMON_CXXFLAGS "${MESON_COMMON_CXXFLAGS} /DWIN32 /D_WINDOWS /W3 /utf-8 /GR /EHsc")
     
     if(DEFINED VCPKG_CRT_LINKAGE AND VCPKG_CRT_LINKAGE STREQUAL dynamic)
-        set(MESON_DEBUG_CFLAGS "${MESON_DEBUG_CFLAGS} /D_DEBUG /MDd /Zi /Ob0 /Od /RTC1")
-        set(MESON_DEBUG_CXXFLAGS "${MESON_DEBUG_CXXFLAGS} /D_DEBUG /MDd /Zi /Ob0 /Od /RTC1")
+        set(MESON_DEBUG_CFLAGS "${MESON_DEBUG_CFLAGS} /D_DEBUG /MDd /Z7 /Ob0 /Od /RTC1")
+        set(MESON_DEBUG_CXXFLAGS "${MESON_DEBUG_CXXFLAGS} /D_DEBUG /MDd /Z7 /Ob0 /Od /RTC1")
         
-        set(MESON_RELEASE_CFLAGS "${MESON_RELEASE_CFLAGS} /MD /O2 /Oi /Gy /DNDEBUG /Zi")
-        set(MESON_RELEASE_CXXFLAGS "${MESON_RELEASE_CXXFLAGS} /MD /O2 /Oi /Gy /DNDEBUG /Zi")
+        set(MESON_RELEASE_CFLAGS "${MESON_RELEASE_CFLAGS} /MD /O2 /Oi /Gy /DNDEBUG /Z7")
+        set(MESON_RELEASE_CXXFLAGS "${MESON_RELEASE_CXXFLAGS} /MD /O2 /Oi /Gy /DNDEBUG /Z7")
     elseif(DEFINED VCPKG_CRT_LINKAGE AND VCPKG_CRT_LINKAGE STREQUAL static)
-        set(MESON_DEBUG_CFLAGS "${MESON_DEBUG_CFLAGS} /D_DEBUG /MTd /Zi /Ob0 /Od /RTC1")
-        set(MESON_DEBUG_CXXFLAGS "${MESON_DEBUG_CXXFLAGS} /D_DEBUG /MTd /Zi /Ob0 /Od /RTC1")
+        set(MESON_DEBUG_CFLAGS "${MESON_DEBUG_CFLAGS} /D_DEBUG /MTd /Z7 /Ob0 /Od /RTC1")
+        set(MESON_DEBUG_CXXFLAGS "${MESON_DEBUG_CXXFLAGS} /D_DEBUG /MTd /Z7 /Ob0 /Od /RTC1")
         
-        set(MESON_RELEASE_CFLAGS "${MESON_RELEASE_CFLAGS} /MT /O2 /Oi /Gy /DNDEBUG /Zi")
-        set(MESON_RELEASE_CXXFLAGS "${MESON_RELEASE_CXXFLAGS} /MT /O2 /Oi /Gy /DNDEBUG /Zi")
+        set(MESON_RELEASE_CFLAGS "${MESON_RELEASE_CFLAGS} /MT /O2 /Oi /Gy /DNDEBUG /Z7")
+        set(MESON_RELEASE_CXXFLAGS "${MESON_RELEASE_CXXFLAGS} /MT /O2 /Oi /Gy /DNDEBUG /Z7")
     endif()
     
     set(MESON_COMMON_LDFLAGS "${MESON_COMMON_LDFLAGS} /DEBUG")
diff --git a/scripts/cmake/vcpkg_download_distfile.cmake b/scripts/cmake/vcpkg_download_distfile.cmake
index 006570195..b8acfc823 100644
--- a/scripts/cmake/vcpkg_download_distfile.cmake
+++ b/scripts/cmake/vcpkg_download_distfile.cmake
@@ -78,7 +78,7 @@ function(vcpkg_download_distfile VAR)
             endif()
         endforeach(url)
 
-        if (NOT ${download_success})
+        if (NOT download_success)
             message(FATAL_ERROR
             "\n"
             "    Failed to download file.\n"
diff --git a/scripts/cmake/vcpkg_find_acquire_program.cmake b/scripts/cmake/vcpkg_find_acquire_program.cmake
index fef62da53..8d167e1c2 100644
--- a/scripts/cmake/vcpkg_find_acquire_program.cmake
+++ b/scripts/cmake/vcpkg_find_acquire_program.cmake
@@ -34,7 +34,8 @@
 ## * [openssl](https://github.com/Microsoft/vcpkg/blob/master/ports/openssl/portfile.cmake)
 ## * [qt5](https://github.com/Microsoft/vcpkg/blob/master/ports/qt5/portfile.cmake)
 function(vcpkg_find_acquire_program VAR)
-  if(${VAR} AND NOT ${VAR} MATCHES "-NOTFOUND")
+  set(EXPANDED_VAR ${${VAR}})
+  if(EXPANDED_VAR)
     return()
   endif()
 
@@ -66,31 +67,19 @@ function(vcpkg_find_acquire_program VAR)
     set(HASH 850b26be5bbbdaeaf45ac39dd27f69f1a85e600c35afbd16b9f621396b3c7a19863ea3ff316b025b578fce0a8280eef2203306a2b3e46ee1389abb65313fb720)
   elseif(VAR MATCHES "PYTHON3")
     set(PROGNAME python)
-    set(PATHS ${DOWNLOADS}/tools/python)
-    set(URL "https://www.python.org/ftp/python/3.5.3/python-3.5.3-embed-win32.zip")
-    set(ARCHIVE "python-3.5.3-embed-win32.zip")
-    set(HASH c8cfdc09d052dc27e4380e8e4bf0d32a4c0def7e03896c1fa6cabc26dde78bb74dbb04e3673cc36e3e307d65a1ef284d69174f0cc80008c83bc6178f192ac5cf)
+    set(SUBDIR "python3")
+    set(PATHS ${DOWNLOADS}/tools/python/${SUBDIR})
+    set(URL "https://www.python.org/ftp/python/3.5.4/python-3.5.4-embed-win32.zip")
+    set(ARCHIVE "python-3.5.4-embed-win32.zip")
+    set(HASH b5240fdc95088c2d7f65d2dd598650f8dd106b49589d94156bd4a078b108c6cabbe7a38ef73e2b2cf00e8312a93d2e587eac2c54ce85540d3c7a26cc60013156)
   elseif(VAR MATCHES "PYTHON2")
-    find_program(PYTHON2 NAMES python2 python PATHS C:/python27 c:/Python27amd64 ENV PYTHON)
-    if(NOT PYTHON2 MATCHES "NOTFOUND")
-        execute_process(
-            COMMAND ${PYTHON2} --version
-            OUTPUT_VARIABLE PYTHON_VER_CHECK_OUT
-            ERROR_VARIABLE PYTHON_VER_CHECK_ERR
-        )
-        set(PYTHON_VER_CHECK "${PYTHON_VER_CHECK_OUT}${PYTHON_VER_CHECK_ERR}")
-        debug_message("PYTHON_VER_CHECK=${PYTHON_VER_CHECK}")
-        if(NOT PYTHON_VER_CHECK MATCHES "Python 2.7")
-            set(PYTHON2 PYTHON2-NOTFOUND)
-            find_program(PYTHON2 NAMES python2 python PATHS C:/python27 ENV PYTHON NO_SYSTEM_ENVIRONMENT_PATH)
-        endif()
-    endif()
-    if(PYTHON2 MATCHES "NOTFOUND")
-        message(FATAL_ERROR "Python 2.7 was not found in the path or by searching inside C:\\Python27.\n"
-        "There is no portable redistributable for Python 2.7, so you will need to install the MSI located at:\n"
-        "    https://www.python.org/ftp/python/2.7.13/python-2.7.13.msi\n"
-        )
-    endif()
+    set(PROGNAME python)
+    set(SUBDIR "python2")
+    set(PATHS ${DOWNLOADS}/tools/python/${SUBDIR})
+    file(TO_NATIVE_PATH "${PATHS}" DESTINATION_NATIVE_PATH)
+    set(URL "https://www.python.org/ftp/python/2.7.14/python-2.7.14.msi")
+    set(ARCHIVE "python2.msi")
+    set(HASH 8c3ad6e527742d99ba96dcfd1098861b14e7207b80d51a54e9b410ab2f36e44e05561ea1527d8e92b3e10808311536260bd9e82db0da3b513fb1be18e108510e)
   elseif(VAR MATCHES "RUBY")
     set(PROGNAME "ruby")
     set(PATHS ${DOWNLOADS}/tools/ruby/rubyinstaller-2.4.1-1-x86/bin)
@@ -152,13 +141,21 @@ function(vcpkg_find_acquire_program VAR)
     set(URL "https://raw.githubusercontent.com/FFmpeg/gas-preprocessor/36bacb4cba27003c572e5bf7a9c4dfe3c9a8d40d/gas-preprocessor.pl")
     set(ARCHIVE "gas-preprocessor.pl")
     set(HASH a25caadccd1457a0fd2abb5a0da9aca1713b2c351d76daf87a4141e52021f51aa09e95a62942c6f0764f79cc1fa65bf71584955b09e62ee7da067b5c82baf6b3)
+  elseif(VAR MATCHES "DARK")
+    set(PROGNAME dark)
+    set(SUBDIR "wix311-binaries")
+    set(PATHS ${DOWNLOADS}/tools/dark/${SUBDIR})
+    set(URL "https://github.com/wixtoolset/wix3/releases/download/wix311rtm/wix311-binaries.zip")
+    set(ARCHIVE "wix311-binaries.zip")
+    set(HASH 74f0fa29b5991ca655e34a9d1000d47d4272e071113fada86727ee943d913177ae96dc3d435eaf494d2158f37560cd4c2c5274176946ebdb17bf2354ced1c516)
   else()
     message(FATAL "unknown tool ${VAR} -- unable to acquire.")
   endif()
 
   macro(do_find)
     if(NOT DEFINED REQUIRED_INTERPRETER)
-      find_program(${VAR} ${PROGNAME} PATHS ${PATHS})
+      find_program(FOUND_PROG ${PROGNAME} PATHS ${PATHS})
+      set(${VAR} ${FOUND_PROG})
     else()
       vcpkg_find_acquire_program(${REQUIRED_INTERPRETER})
       find_file(SCRIPT ${SCRIPTNAME} PATHS ${PATHS})
@@ -167,7 +164,8 @@ function(vcpkg_find_acquire_program VAR)
   endmacro()
 
   do_find()
-  if(${VAR} MATCHES "-NOTFOUND")
+  set(FOUND_PROG ${${VAR}})
+  if(FOUND_PROG MATCHES "-NOTFOUND")
     file(DOWNLOAD ${URL} ${DOWNLOADS}/${ARCHIVE}
       EXPECTED_HASH SHA512=${HASH}
       SHOW_PROGRESS
@@ -178,7 +176,7 @@ function(vcpkg_find_acquire_program VAR)
     else()
       get_filename_component(ARCHIVE_EXTENSION ${ARCHIVE} EXT)
       string(TOLOWER "${ARCHIVE_EXTENSION}" ARCHIVE_EXTENSION)
-      if(${ARCHIVE_EXTENSION} STREQUAL ".msi")
+      if(ARCHIVE_EXTENSION STREQUAL ".msi")
         file(TO_NATIVE_PATH "${DOWNLOADS}/${ARCHIVE}" ARCHIVE_NATIVE_PATH)
         file(TO_NATIVE_PATH "${DOWNLOADS}/tools/${PROGNAME}/${SUBDIR}" DESTINATION_NATIVE_PATH)
         execute_process(
diff --git a/scripts/cmake/vcpkg_from_bitbucket.cmake b/scripts/cmake/vcpkg_from_bitbucket.cmake
new file mode 100644
index 000000000..227de5141
--- /dev/null
+++ b/scripts/cmake/vcpkg_from_bitbucket.cmake
@@ -0,0 +1,190 @@
+## # vcpkg_from_bitbucket
+##
+## Download and extract a project from Bitbucket.
+## Enables support for installing HEAD `vcpkg.exe install --head <port>`.
+##
+## ## Usage:
+## ```cmake
+## vcpkg_from_bitbucket(
+##     OUT_SOURCE_PATH <SOURCE_PATH>
+##     REPO <Microsoft/cpprestsdk>
+##     [REF <v2.0.0>]
+##     [SHA512 <45d0d7f8cc350...>]
+##     [HEAD_REF <master>]
+## )
+## ```
+##
+## ## Parameters:
+## ### OUT_SOURCE_PATH
+## Specifies the out-variable that will contain the extracted location.
+##
+## This should be set to `SOURCE_PATH` by convention.
+##
+## ### REPO
+## The organization or user and repository on GitHub.
+##
+## ### REF
+## A stable git commit-ish (ideally a tag) that will not change contents. **This should not be a branch.**
+##
+## For repositories without official releases, this can be set to the full commit id of the current latest master.
+##
+## If `REF` is specified, `SHA512` must also be specified.
+##
+## ### SHA512
+## The SHA512 hash that should match the archive (https://bitbucket.com/${REPO}/get/${REF}.tar.gz).
+##
+## This is most easily determined by first setting it to `1`, then trying to build the port. The error message will contain the full hash, which can be copied back into the portfile.
+##
+## ### HEAD_REF
+## The unstable git commit-ish (ideally a branch) to pull for `--head` builds.
+##
+## For most projects, this should be `master`. The chosen branch should be one that is expected to be always buildable on all supported platforms.
+##
+## ## Notes:
+## At least one of `REF` and `HEAD_REF` must be specified, however it is preferable for both to be present.
+##
+## This exports the `VCPKG_HEAD_VERSION` variable during head builds.
+##
+## ## Examples:
+##
+## * [blaze](https://github.com/Microsoft/vcpkg/blob/master/ports/blaze/portfile.cmake)
+function(vcpkg_from_bitbucket)
+    set(oneValueArgs OUT_SOURCE_PATH REPO REF SHA512 HEAD_REF)
+    set(multipleValuesArgs)
+    cmake_parse_arguments(_vdud "" "${oneValueArgs}" "${multipleValuesArgs}" ${ARGN})
+
+    if(NOT _vdud_OUT_SOURCE_PATH)
+        message(FATAL_ERROR "OUT_SOURCE_PATH must be specified.")
+    endif()
+
+    if((_vdud_REF AND NOT _vdud_SHA512) OR (NOT _vdud_REF AND _vdud_SHA512))
+        message(FATAL_ERROR "SHA512 must be specified if REF is specified.")
+    endif()
+
+    if(NOT _vdud_REPO)
+        message(FATAL_ERROR "The Bitbucket repository must be specified.")
+    endif()
+
+    if(NOT _vdud_REF AND NOT _vdud_HEAD_REF)
+        message(FATAL_ERROR "At least one of REF and HEAD_REF must be specified.")
+    endif()
+
+    string(REGEX REPLACE ".*/" "" REPO_NAME ${_vdud_REPO})
+    string(REGEX REPLACE "/.*" "" ORG_NAME ${_vdud_REPO})
+
+    macro(set_SOURCE_PATH BASE BASEREF)
+        set(SOURCE_PATH "${BASE}/${ORG_NAME}-${REPO_NAME}-${BASEREF}")
+        if(EXISTS ${SOURCE_PATH})
+            set(${_vdud_OUT_SOURCE_PATH} "${SOURCE_PATH}" PARENT_SCOPE)
+        else()
+            # Sometimes GitHub strips a leading 'v' off the REF.
+            string(REGEX REPLACE "^v" "" REF ${BASEREF})
+            set(SOURCE_PATH "${BASE}/${ORG_NAME}-${REPO_NAME}-${REF}")
+            if(EXISTS ${SOURCE_PATH})
+                set(${_vdud_OUT_SOURCE_PATH} "${SOURCE_PATH}" PARENT_SCOPE)
+            else()
+                message(FATAL_ERROR "Could not determine source path: '${BASE}/${ORG_NAME}-${REPO_NAME}-${BASEREF}' does not exist")
+            endif()
+        endif()
+    endmacro()
+
+    if(VCPKG_USE_HEAD_VERSION AND NOT _vdud_HEAD_REF)
+        message(STATUS "Package does not specify HEAD_REF. Falling back to non-HEAD version.")
+        set(VCPKG_USE_HEAD_VERSION OFF)
+    endif()
+    
+    # Handle --no-head scenarios
+    if(NOT VCPKG_USE_HEAD_VERSION)
+        if(NOT _vdud_REF)
+            message(FATAL_ERROR "Package does not specify REF. It must built using --head.")
+        endif()
+        
+        set(URL "https://bitbucket.com/${ORG_NAME}/${REPO_NAME}/get/${_vdud_REF}.tar.gz")
+        set(downloaded_file_path "${DOWNLOADS}/${ORG_NAME}-${REPO_NAME}-${_vdud_REF}.tar.gz")
+
+        file(DOWNLOAD "https://api.bitbucket.com/2.0/repositories/${ORG_NAME}/${REPO_NAME}/refs/tags/${_vdud_REF}"
+            ${downloaded_file_path}.version
+            STATUS download_status
+        )
+        list(GET download_status 0 status_code)
+        if ("${status_code}" STREQUAL "0")
+            # Parse the github refs response with regex.
+            # TODO: use some JSON swiss-army-knife utility instead.
+            file(READ "${downloaded_file_path}.version" _contents)
+            string(REGEX MATCH "\"hash\": \"[a-f0-9]+\"" x "${_contents}")
+            string(REGEX REPLACE "\"hash\": \"([a-f0-9]+)\"" "\\1" _version ${x})
+            string(SUBSTRING ${_version} 0 12 _version) # Get the 12 first numbers from commit hash
+        else()
+            set(_version ${_vdud_REF})
+        endif()
+        
+        vcpkg_download_distfile(ARCHIVE
+            URLS "https://bitbucket.com/${ORG_NAME}/${REPO_NAME}/get/${_vdud_REF}.tar.gz"
+            SHA512 "${_vdud_SHA512}"
+            FILENAME "${ORG_NAME}-${REPO_NAME}-${_vdud_REF}.tar.gz"
+        )
+        vcpkg_extract_source_archive_ex(ARCHIVE "${ARCHIVE}")
+        set_SOURCE_PATH(${CURRENT_BUILDTREES_DIR}/src ${_version})
+        return()
+    endif()
+
+    # The following is for --head scenarios
+    set(URL "https://bitbucket.com/${ORG_NAME}/${REPO_NAME}/get/${_vdud_HEAD_REF}.tar.gz")
+    set(downloaded_file_path "${DOWNLOADS}/${ORG_NAME}-${REPO_NAME}-${_vdud_HEAD_REF}.tar.gz")
+
+    if(_VCPKG_NO_DOWNLOADS)
+        if(NOT EXISTS ${downloaded_file_path} OR NOT EXISTS ${downloaded_file_path}.version)
+            message(FATAL_ERROR "Downloads are disabled, but '${downloaded_file_path}' does not exist.")
+        endif()
+        message(STATUS "Using cached ${downloaded_file_path}")
+    else()
+        if(EXISTS ${downloaded_file_path})
+            message(STATUS "Purging cached ${downloaded_file_path} to fetch latest (use --no-downloads to suppress)")
+            file(REMOVE ${downloaded_file_path})
+        endif()
+        if(EXISTS ${downloaded_file_path}.version)
+            file(REMOVE ${downloaded_file_path}.version)
+        endif()
+        if(EXISTS ${CURRENT_BUILDTREES_DIR}/src/head)
+            file(REMOVE_RECURSE ${CURRENT_BUILDTREES_DIR}/src/head)
+        endif()
+
+        # Try to download the file and version information from bitbucket.
+        message(STATUS "Downloading ${URL}...")
+        file(DOWNLOAD "https://api.bitbucket.com/2.0/repositories/${ORG_NAME}/${REPO_NAME}/refs/branches/${_vdud_HEAD_REF}"
+            ${downloaded_file_path}.version
+            STATUS download_status
+        )
+        list(GET download_status 0 status_code)
+        if (NOT "${status_code}" STREQUAL "0")
+            file(REMOVE ${downloaded_file_path}.version)
+            message(FATAL_ERROR "Downloading version info for ${URL}... Failed. Status: ${download_status}")
+        endif()
+
+        file(DOWNLOAD ${URL} ${downloaded_file_path} STATUS download_status)
+        list(GET download_status 0 status_code)
+        if (NOT "${status_code}" STREQUAL "0")
+            file(REMOVE ${downloaded_file_path})
+            message(FATAL_ERROR "Downloading ${URL}... Failed. Status: ${download_status}")
+        else()
+            message(STATUS "Downloading ${URL}... OK")
+        endif()
+    endif()
+
+    vcpkg_extract_source_archive_ex(
+        ARCHIVE "${downloaded_file_path}"
+        WORKING_DIRECTORY "${CURRENT_BUILDTREES_DIR}/src/head"
+    )
+
+    # Parse the github refs response with regex.
+    # TODO: use some JSON swiss-army-knife utility instead.
+    file(READ "${downloaded_file_path}.version" _contents)
+    string(REGEX MATCH "\"hash\": \"[a-f0-9]+\"" x "${_contents}")
+    string(REGEX REPLACE "\"hash\": \"([a-f0-9]+)\"" "\\1" _version ${x})
+    string(SUBSTRING ${_version} 0 12 _vdud_HEAD_REF) # Get the 12 first numbers from commit hash
+    
+    # exports VCPKG_HEAD_VERSION to the caller. This will get picked up by ports.cmake after the build.
+    set(VCPKG_HEAD_VERSION ${_version} PARENT_SCOPE)
+
+    set_SOURCE_PATH(${CURRENT_BUILDTREES_DIR}/src/head ${_vdud_HEAD_REF})
+endfunction()
diff --git a/scripts/cmake/vcpkg_install_cmake.cmake b/scripts/cmake/vcpkg_install_cmake.cmake
index f778007ef..ab72d054e 100644
--- a/scripts/cmake/vcpkg_install_cmake.cmake
+++ b/scripts/cmake/vcpkg_install_cmake.cmake
@@ -4,15 +4,15 @@
 ##
 ## ## Usage:
 ## ```cmake
-## vcpkg_install_cmake([MSVC_64_TOOLSET])
+## vcpkg_install_cmake(...)
 ## ```
 ##
 ## ## Parameters:
-## ### MSVC_64_TOOLSET
-## This adds the `/p:PreferredToolArchitecture=x64` switch if the underlying buildsystem is MSBuild. Some large projects can run out of memory when linking if they use the 32-bit hosted tools.
+## See [`vcpkg_build_cmake()`](vcpkg_build_cmake.md).
 ##
 ## ## Notes:
-## This command should be preceeded by a call to [`vcpkg_configure_cmake()`](vcpkg_configure_cmake.md).
+## This command transparently forwards to [`vcpkg_build_cmake()`](vcpkg_build_cmake.md), adding a `TARGET install`
+## parameter.
 ##
 ## ## Examples:
 ##
@@ -21,43 +21,5 @@
 ## * [poco](https://github.com/Microsoft/vcpkg/blob/master/ports/poco/portfile.cmake)
 ## * [opencv](https://github.com/Microsoft/vcpkg/blob/master/ports/opencv/portfile.cmake)
 function(vcpkg_install_cmake)
-    cmake_parse_arguments(_bc "MSVC_64_TOOLSET;DISABLE_PARALLEL" "" "" ${ARGN})
-
-    set(MSVC_EXTRA_ARGS
-        "/p:VCPkgLocalAppDataDisabled=true"
-        "/p:UseIntelMKL=No"
-    )
-
-    # Specifies the architecture of the toolset, NOT the architecture of the produced binary
-    # This can help libraries that cause the linker to run out of memory.
-    # https://support.microsoft.com/en-us/help/2891057/linker-fatal-error-lnk1102-out-of-memory
-    if (_bc_MSVC_64_TOOLSET)
-        list(APPEND MSVC_EXTRA_ARGS "/p:PreferredToolArchitecture=x64")
-    endif()
-
-    if (NOT _bc_DISABLE_PARALLEL)
-        list(APPEND MSVC_EXTRA_ARGS "/m")
-    endif()
-    
-    if(EXISTS ${CURRENT_BUILDTREES_DIR}/${TARGET_TRIPLET}-rel/build.ninja)
-        set(BUILD_ARGS -v) # verbose output
-    else()
-        set(BUILD_ARGS ${MSVC_EXTRA_ARGS})
-    endif()
-
-    message(STATUS "Package ${TARGET_TRIPLET}-rel")
-    vcpkg_execute_required_process(
-        COMMAND ${CMAKE_COMMAND} --build . --config Release --target install -- ${BUILD_ARGS}
-        WORKING_DIRECTORY ${CURRENT_BUILDTREES_DIR}/${TARGET_TRIPLET}-rel
-        LOGNAME package-${TARGET_TRIPLET}-rel
-    )
-    message(STATUS "Package ${TARGET_TRIPLET}-rel done")
-
-    message(STATUS "Package ${TARGET_TRIPLET}-dbg")
-    vcpkg_execute_required_process(
-        COMMAND ${CMAKE_COMMAND} --build . --config Debug --target install -- ${BUILD_ARGS}
-        WORKING_DIRECTORY ${CURRENT_BUILDTREES_DIR}/${TARGET_TRIPLET}-dbg
-        LOGNAME package-${TARGET_TRIPLET}-dbg
-    )
-    message(STATUS "Package ${TARGET_TRIPLET}-dbg done")
+    vcpkg_build_cmake(LOGFILE_ROOT install TARGET install ${ARGN})
 endfunction()